2_2_4_45

2014-12-05 13:22:00 +03:00
1 parent b1d09ad9f4
commit 89042d6a6a
@@ -0,0 +1,90 @@
+////////////////////////////////////////////////////////////////////////////////
+// Подсистема "Электронная подпись".
+// 
+////////////////////////////////////////////////////////////////////////////////
+
+#Область СлужебныеПроцедурыИФункции
+
+// Только для внутреннего использования.
+Функция ОбщиеНастройки() Экспорт
+	
+	ОбщиеНастройки = Новый Структура;
+	
+	УстановитьПривилегированныйРежим(Истина);
+	
+	ОбщиеНастройки.Вставить("ИспользоватьЭлектронныеПодписи",
+		Константы.ИспользоватьЭлектронныеПодписи.Получить());
+	
+	ОбщиеНастройки.Вставить("ИспользоватьШифрование",
+		Константы.ИспользоватьШифрование.Получить());
+	
+	Если ОбщегоНазначенияПовтИсп.РазделениеВключено()
+	 Или ОбщегоНазначения.ИнформационнаяБазаФайловая()
+	   И Не ОбщегоНазначенияКлиентСервер.КлиентПодключенЧерезВебСервер() Тогда
+		
+		ОбщиеНастройки.Вставить("ПроверятьЭлектронныеПодписиНаСервере", Ложь);
+		ОбщиеНастройки.Вставить("СоздаватьЭлектронныеПодписиНаСервере", Ложь);
+	Иначе
+		ОбщиеНастройки.Вставить("ПроверятьЭлектронныеПодписиНаСервере",
+			Константы.ПроверятьЭлектронныеПодписиНаСервере.Получить());
+		
+		ОбщиеНастройки.Вставить("СоздаватьЭлектронныеПодписиНаСервере",
+			Константы.СоздаватьЭлектронныеПодписиНаСервере.Получить());
+	КонецЕсли;
+	
+	// Использование подсистем.
+	// 1. Подсистема Контактная информация  - российский адрес.
+	// 2. Подсистема Адресный классификатор - код региона по наименованию.
+	// 3. Подсистема Печать - стандартная печатная форма для заявления на выпуск сертификата.
+	
+	ОбщиеНастройки.Вставить("ЗаявлениеНаВыпускСертификатаДоступно",
+		  ОбщегоНазначения.ПодсистемаСуществует("СтандартныеПодсистемы.КонтактнаяИнформация")
+		И ОбщегоНазначения.ПодсистемаСуществует("СтандартныеПодсистемы.АдресныйКлассификатор")
+		И ОбщегоНазначения.ПодсистемаСуществует("СтандартныеПодсистемы.Печать"));
+	
+	Запрос = Новый Запрос;
+	Запрос.Текст =
+	"ВЫБРАТЬ
+	|	Программы.Ссылка,
+	|	Программы.Наименование КАК Наименование,
+	|	Программы.ИмяПрограммы,
+	|	Программы.ТипПрограммы,
+	|	Программы.АлгоритмПодписи,
+	|	Программы.АлгоритмХеширования,
+	|	Программы.АлгоритмШифрования
+	|ИЗ
+	|	Справочник.ПрограммыЭлектроннойПодписиИШифрования КАК Программы
+	|ГДЕ
+	|	НЕ Программы.ПометкаУдаления
+	|
+	|УПОРЯДОЧИТЬ ПО
+	|	Наименование";
+	
+	Выборка = Запрос.Выполнить().Выбрать();
+	ОписанияПрограмм = Новый Массив;
+	ПоставляемыеНастройки = Справочники.ПрограммыЭлектроннойПодписиИШифрования.ПоставляемыеНастройкиПрограмм();
+	
+	Пока Выборка.Следующий() Цикл
+		Отбор = Новый Структура("ИмяПрограммы, ТипПрограммы", Выборка.ИмяПрограммы, Выборка.ТипПрограммы);
+		Строки = ПоставляемыеНастройки.НайтиСтроки(Отбор);
+		Идентификатор = ?(Строки.Количество() = 0, "", Строки[0].Идентификатор);
+		
+		Описание = Новый Структура;
+		Описание.Вставить("Ссылка",              Выборка.Ссылка);
+		Описание.Вставить("Наименование",        Выборка.Наименование);
+		Описание.Вставить("ИмяПрограммы",        Выборка.ИмяПрограммы);
+		Описание.Вставить("ТипПрограммы",        Выборка.ТипПрограммы);
+		Описание.Вставить("АлгоритмПодписи",     Выборка.АлгоритмПодписи);
+		Описание.Вставить("АлгоритмХеширования", Выборка.АлгоритмХеширования);
+		Описание.Вставить("АлгоритмШифрования",  Выборка.АлгоритмШифрования);
+		Описание.Вставить("Идентификатор",       Идентификатор);
+		ОписанияПрограмм.Добавить(Новый ФиксированнаяСтруктура(Описание));
+	КонецЦикла;
+	
+	ОбщиеНастройки.Вставить("ОписанияПрограмм", Новый ФиксированныйМассив(ОписанияПрограмм));
+	
+	Возврат Новый ФиксированнаяСтруктура(ОбщиеНастройки);
+	
+КонецФункции
+
+#КонецОбласти